AutoCAD顧問
還沒有註冊嗎...即日起免費註冊,所有最完整的AutoCAD討論、教學及資源都在論壇裡喔~

[討論]局部放大功能無法修剪圖塊!

上一篇主題 下一篇主題 向下

[討論]局部放大功能無法修剪圖塊!

發表 由 djh1006 于 2014-01-10, 02:38

本程式根據葉旭坤局部放大程式改編,對於相交的圖塊無法修剪,請各位高手幫忙修改成可以修剪圖塊的功能,謝謝
<雖然燕秀工具箱裡有很好用的局部放大功能(可以修剪圖塊),可是我不想裝了燕秀卻只用到局部放大的功能,因為我是畫沖壓模具圖的>

代碼:
;;;局部放大===========================================
;;;全部變數JBHD-A(標記字母),JBHD-SC(放大倍數)
(DEFUN C:DJH_220( / CIR_R CLAY CP DATA DATA_A DATA_B DATA_C DATA_D DATA_G DIMCE DIMT HD IN_P JBHD-STRD JBHD-STRIN LAST1 LASTP LASTT MODE OSMO PD SCA_TT STRD STRD1 STRD2 X)
 (setvar "CMDECHO" 0)

;===中斷處理的程式==========
 (defun *error*()
   (princ "錯誤!")
   (setvar "OSMODE" 4151)
   (setvar "AUTOSNAP" 63)
   (princ)
 )
 (defun useerr(s)
   (setq *error* olderr)
   (setvar "CECOLOR" CCLR)
   (setvar "CELTYPE" CLTP)
   (setvar "OSMODE" OSP)
   (setvar "ORTHOMODE" MODE)
   (setvar "AUTOSNAP" 63)
   (setvar "DIMTOFL" DIMT)
   (command "UNDO" "E")
   (princ)
 )
 (setq olderr *error* *error* useerr)
;===========================

 (command "UNDO" "BE")
 (setq
   CCLR (getvar "CECOLOR")
   CLTP (getvar "CELTYPE")
   OSP (getvar "OSMODE");鎖點
   MODE (getvar "ORTHOMODE");正交
   DIMT (getvar "DIMTOFL")
   DIMCE (getvar "DIMCEN")
 )
 (setvar "ORTHOMODE" 0)
 (initget 1)
 (setq CP (getpoint "\n局部放大中心點:"))
 (setvar "OSMODE" 0)
 (setvar "DIMCEN" 0)
 (setvar "CELTYPE" "PHANTOM")
 (setvar "CECOLOR" "200")
 (prompt "\n放大範圍:")
 (command "_.CIRCLE" CP PAUSE)
 (setq LAST1 (entlast));放大範圍的圓
 (setq LASTT (cons LAST1 (list (getvar "LASTPOINT"))));(圓.圓心)
 (setq CIR_R (cdr (assoc 40 (entget LAST1))))
 (setq DATA_G (mapcar
  'ANGTOF
  '("0" "15"
   "30" "45"
   "60" "75"
   "90" "105"
   "120" "135"
   "150" "165"
   "180" "195"
   "210" "225"
   "240" "255"
   "270" "285"
   "300" "315"
   "330" "345"
   "0"
  )
       ); end mapcar
 ); end setq
 (setq DATA_A (mapcar
  '(lambda (X)
     (polar CP X CIR_R)
   )
  DATA_G
       )
 )
 (setq DATA (ssget "CP" DATA_A '((-4 . "<NOT") (0 . "TEXT")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "MTEXT")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "DIMENSION")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "HATCH")
      (-4 . "NOT>")
     )
     ); end ssget
 )
 (setq DATA (ssdel LAST1 DATA));去除選集中的圓
 (if (NUMBERP JBHD-A) (setq JBHD-A (1+ JBHD-A)) (setq JBHD-A 65));NUMBERP 判斷 JBHD-A 是否為數字
 (setq JBHD-STRD (chr JBHD-A));將數字內碼轉成英文字65=A
 (setq JBHD-strin (strcat "\n放大標記字母<" JBHD-STRD ">:"))
 (setq STRD1 (getstring JBHD-strin))
 (if (= STRD1 "") (setq STRD1 JBHD-STRD))
 (setq STRD2 (strcat STRD1 " 放大"))
 (setq HD (* 1.5 (getvar "DIMTXT")))
 (command "_.DIMTOH" "ON")
 (command "_.DIMTOFL" "off")
 (command "_.DIMDIAMETER" LASTT "M" STRD1 pause);
 (setvar "DIMCEN" DIMCE)
 (prompt "\n放大圖形放置中心點:")
 (setvar "OSMODE" OSP)
 (command "_.COPY" LAST1 "" CP PAUSE)
 (setq
   LASTP (getvar "LASTPOINT")
   LAST1 (entlast)
 )
 (command "_.COPY" DATA "" CP LASTP)
 (setq CIR_R (/ CIR_R (cos (ANGTOF "7.5"))))
 (setq CP LASTP)
 (setq DATA_B (mapcar
   '(LAMBDA (X)
   (polar CP X (+ CIR_R 1))
   )
   DATA_G
     )
 )
 (setq DATA_C DATA_B)
 (setq DATA_D DATA_B)
 (setvar "OSMODE" 0)
 (command "_.TRIM" LAST1 "" "F")
 (while (car DATA_B)
   (setq IN_P (car DATA_B))
   (command IN_P)
   (setq DATA_B (cdr DATA_B))
 ); end while
 (command "" "")
 (command "_.TRIM" LAST1 "" "F")
 (while (car DATA_C)
   (setq IN_P (car DATA_C))
   (command IN_P)
   (setq DATA_C (cdr DATA_C))
 ); end while
 (command "" "")
 (setvar "ATTMODE" 1)
 (initget 6)

 (if (not (NUMBERP JBHD-SC)) (setq JBHD-SC 2))

 (setq Q-SC (strcat "\n放大倍率<" (rtos JBHD-SC 2) ">:"))
 (setq JBHD-SC1 (getreal Q-SC))
 (if (not (NUMBERP JBHD-SC1)) (setq JBHD-SC1 JBHD-SC))
 (setq JBHD-SC JBHD-SC1)
 (if (>= JBHD-SC 10)
   (if (= "0" (substr (rtos JBHD-SC 2 2) 4 1))
     (setq sca_tt 0)
     (setq sca_tt 1)
   )
   (if (= "0" (substr (rtos JBHD-SC 2 2) 3 1))
     (setq sca_tt 0)
     (setq sca_tt 1)
   )
 )
 (command "_.SCALE" "CP")
 (while (car DATA_D)
   (setq IN_P (car DATA_D))
   (command IN_P)
   (setq DATA_D (cdr DATA_D))
 );end while
 (command "" "" LASTP JBHD-SC)
 (setq STRD (strcat STRD2 " " (rtos JBHD-SC 2 SCA_TT) ":1"))
 (initget 33)
 (setvar "ORTHOMODE" 1)
 (setq PD (getpoint CP "\n標記字母放置點:"))
 (setvar "CELTYPE" "BYLAYER")
 (setvar "CECOLOR" "BYLAYER")
 (command "_.TEXT" "_J" "_M" PD HD 0 STRD)
 (command "_.UNDO" "_E")
 (setvar "CECOLOR" CCLR)
 (setvar "CELTYPE" CLTP)
 (setvar "ORTHOMODE" MODE)
 (setvar "AUTOSNAP" 63)
 (setvar "OSMODE" OSP)
 (setvar "DIMTOFL" DIMT)

;===將*error*回覆成預設功能===
   (setq *error* olderr)
;===========================

 (princ)
)

備用: https://app.box.com/s/b4lsu6sqktwwrjstce5w
附件
DJH_220.zip 您無權下載這里的附件。(2 Kb) 下載 5 次
avatar
djh1006
中級會員
中級會員

文章總數 : 156
年齡 : 46
來自 : 彰化縣員林鎮中山路二段369巷二弄15-14號
職業 : 沖壓模具設計工程師
愛好 : UG,SOLIDWORKS,AUTOCAD 2D,autolisp
個性 : 內向偏外
使用年資 : 18以上
使用版本 : 2014
積分 : 6
經驗值 : 3401
威望值 : 294
注冊日期 : 2011-06-16
男 獅子座 豬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 djh1006 于 2014-01-12, 10:03

再來比較2個局部放大功能的差別
avatar
djh1006
中級會員
中級會員

文章總數 : 156
年齡 : 46
來自 : 彰化縣員林鎮中山路二段369巷二弄15-14號
職業 : 沖壓模具設計工程師
愛好 : UG,SOLIDWORKS,AUTOCAD 2D,autolisp
個性 : 內向偏外
使用年資 : 18以上
使用版本 : 2014
積分 : 6
經驗值 : 3401
威望值 : 294
注冊日期 : 2011-06-16
男 獅子座 豬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 shenhung 于 2014-01-12, 12:43

多加了炸開圖塊的附程式.!! 如果原始圖塊圖元在第0層建立..則圖塊炸開後.圖元會回到第0層
代碼:

;;;局部放大===========================================
;;;全部變數JBHD-A(標記字母),JBHD-SC(放大倍數)
(DEFUN C:DJH_220( / CIR_R CLAY CP DATA DATA_A DATA_B DATA_C DATA_D DATA_G DIMCE DIMT HD IN_P JBHD-STRD JBHD-STRIN LAST1 LASTP LASTT MODE OSMO PD SCA_TT STRD STRD1 STRD2 X)
 (setvar "CMDECHO" 0)

;===中斷處理的程式==========
 (defun *error*()
   (princ "錯誤!")
   (setvar "OSMODE" 4151)
   (setvar "AUTOSNAP" 63)
   (princ)
 )
 (defun useerr(s)
   (setq *error* olderr)
   (setvar "CECOLOR" CCLR)
   (setvar "CELTYPE" CLTP)
   (setvar "OSMODE" OSP)
   (setvar "ORTHOMODE" MODE)
   (setvar "AUTOSNAP" 63)
   (setvar "DIMTOFL" DIMT)
   (command "UNDO" "E")
   (princ)
 )
 (setq olderr *error* *error* useerr)
;===========================

 (command "UNDO" "BE")
 (setq
   CCLR (getvar "CECOLOR")
   CLTP (getvar "CELTYPE")
   OSP (getvar "OSMODE");鎖點
   MODE (getvar "ORTHOMODE");正交
   DIMT (getvar "DIMTOFL")
   DIMCE (getvar "DIMCEN")
 )
 (setvar "ORTHOMODE" 0)
 (initget 1)
 (setq CP (getpoint "\n局部放大中心點:"))
 (setvar "OSMODE" 0)
 (setvar "DIMCEN" 0)
 (setvar "CELTYPE" "PHANTOM")
 (setvar "CECOLOR" "200")
 (prompt "\n放大範圍:")
 (command "_.CIRCLE" CP PAUSE)
 (setq LAST1 (entlast));放大範圍的圓
 (setq LASTT (cons LAST1 (list (getvar "LASTPOINT"))));(圓.圓心)
 (setq CIR_R (cdr (assoc 40 (entget LAST1))))
 (setq DATA_G (mapcar
  'ANGTOF
  '("0" "15"
   "30" "45"
   "60" "75"
   "90" "105"
   "120" "135"
   "150" "165"
   "180" "195"
   "210" "225"
   "240" "255"
   "270" "285"
   "300" "315"
   "330" "345"
   "0"
  )
       ); end mapcar
 ); end setq
 (setq DATA_A (mapcar
  '(lambda (X)
     (polar CP X CIR_R)
   )
  DATA_G
       )
 )
 
 (setq DATA (ssget "CP" DATA_A '((-4 . "<NOT") (0 . "TEXT")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "MTEXT")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "DIMENSION")
      (-4 . "NOT>")
      (-4 . "<NOT")
      (0 . "HATCH")
      (-4 . "NOT>")
     )
     ); end ssget
 )
 (setq DATA (ssdel LAST1 DATA));去除選集中的圓
 (if (NUMBERP JBHD-A) (setq JBHD-A (1+ JBHD-A)) (setq JBHD-A 65));NUMBERP 判斷 JBHD-A 是否為數字
 (setq JBHD-STRD (chr JBHD-A));將數字內碼轉成英文字65=A
 (setq JBHD-strin (strcat "\n放大標記字母<" JBHD-STRD ">:"))
 (setq STRD1 (getstring JBHD-strin))
 (if (= STRD1 "") (setq STRD1 JBHD-STRD))
 (setq STRD2 (strcat STRD1 " 放大"))
 (setq HD (* 1.5 (getvar "DIMTXT")))
 (command "_.DIMTOH" "ON")
 (command "_.DIMTOFL" "off")
 (command "_.DIMDIAMETER" LASTT "M" STRD1 pause);
 (setvar "DIMCEN" DIMCE)
 (prompt "\n放大圖形放置中心點:")
 (setvar "OSMODE" OSP)
 (command "_.COPY" LAST1 "" CP PAUSE)
 (setq
   LASTP (getvar "LASTPOINT")
   LAST1 (entlast)
 )
  
 (SETQ SN1 LAST1) ;取得複制前的最後一個圖元.
  
 (command "_.COPY" DATA "" CP LASTP)
  
 (exp_insert) ;<-炸破副程式
  
 (setq CIR_R (/ CIR_R (cos (ANGTOF "7.5"))))
 (setq CP LASTP)
 (setq DATA_B (mapcar
   '(LAMBDA (X)
   (polar CP X (+ CIR_R 1))
   )
   DATA_G
     )
 )
 (setq DATA_C DATA_B)
 (setq DATA_D DATA_B)
 (setvar "OSMODE" 0)
 (command "_.TRIM" LAST1 "" "F")
 (while (car DATA_B)
   (setq IN_P (car DATA_B))
   (command IN_P)
   (setq DATA_B (cdr DATA_B))
 ); end while
 (command "" "")
 (command "_.TRIM" LAST1 "" "F")
 (while (car DATA_C)
   (setq IN_P (car DATA_C))
   (command IN_P)
   (setq DATA_C (cdr DATA_C))
 ); end while
 (command "" "")
 (setvar "ATTMODE" 1)
 (initget 6)

 (if (not (NUMBERP JBHD-SC)) (setq JBHD-SC 2))

 (setq Q-SC (strcat "\n放大倍率<" (rtos JBHD-SC 2) ">:"))
 (setq JBHD-SC1 (getreal Q-SC))
 (if (not (NUMBERP JBHD-SC1)) (setq JBHD-SC1 JBHD-SC))
 (setq JBHD-SC JBHD-SC1)
 (if (>= JBHD-SC 10)
   (if (= "0" (substr (rtos JBHD-SC 2 2) 4 1))
     (setq sca_tt 0)
     (setq sca_tt 1)
   )
   (if (= "0" (substr (rtos JBHD-SC 2 2) 3 1))
     (setq sca_tt 0)
     (setq sca_tt 1)
   )
 )
 (command "_.SCALE" "CP")
 (while (car DATA_D)
   (setq IN_P (car DATA_D))
   (command IN_P)
   (setq DATA_D (cdr DATA_D))
 );end while
 (command "" "" LASTP JBHD-SC)
 (setq STRD (strcat STRD2 " " (rtos JBHD-SC 2 SCA_TT) ":1"))
 (initget 33)
 (setvar "ORTHOMODE" 1)
 (setq PD (getpoint CP "\n標記字母放置點:"))
 (setvar "CELTYPE" "BYLAYER")
 (setvar "CECOLOR" "BYLAYER")
 (command "_.TEXT" "_J" "_M" PD HD 0 STRD)
 (command "_.UNDO" "_E")
 (setvar "CECOLOR" CCLR)
 (setvar "CELTYPE" CLTP)
 (setvar "ORTHOMODE" MODE)
 (setvar "AUTOSNAP" 63)
 (setvar "OSMODE" OSP)
 (setvar "DIMTOFL" DIMT)

;===將*error*回覆成預設功能===
   (setq *error* olderr)
;===========================

 (princ)
)
;;--------------------------------------------------------------
(defun exp_insert(/ en-name)
  (setq en (entnext sn1))
  (while (/= en nil)
  (setq en-name (dxfa 0 en))
  (if (= en-name "INSERT")(command "explode" en))
  (setq en (entnext en))
  )
)

備用: https://app.box.com/s/hjro2toua0z0l6nyngcm
附件
DJH_220-shenhung.zip 您無權下載這里的附件。(2 Kb) 下載 12 次
avatar
shenhung
高級會員
高級會員

文章總數 : 238
年齡 : 50
來自 : 新北市
職業 : 塑膠模具設計.AUTOLISP
愛好 : 音樂
個性 : 隨和
使用年資 : 18年
使用版本 : 2010
積分 : 15
經驗值 : 5002
威望值 : 913
注冊日期 : 2009-06-03
男 摩羯座 馬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 djh1006 于 2014-01-12, 13:09

謝謝shenhung的改版,太好了,明天去公司試試,我又學到一招了
avatar
djh1006
中級會員
中級會員

文章總數 : 156
年齡 : 46
來自 : 彰化縣員林鎮中山路二段369巷二弄15-14號
職業 : 沖壓模具設計工程師
愛好 : UG,SOLIDWORKS,AUTOCAD 2D,autolisp
個性 : 內向偏外
使用年資 : 18以上
使用版本 : 2014
積分 : 6
經驗值 : 3401
威望值 : 294
注冊日期 : 2011-06-16
男 獅子座 豬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 li60830 于 2016-06-03, 03:41

為什麼我下載不了啊~樓主大人~
avatar
li60830
初級會員
初級會員

文章總數 : 310
年齡 : 46
來自 : 亞洲
職業 : 待業
愛好 : 電動~游泳~看書~看影集
個性 : 固執
使用年資 : 18年
使用版本 : 2008 - 2014
積分 : 2
經驗值 : 3264
威望值 : 304
注冊日期 : 2013-04-17
藍鵲697號
男 處女座 豬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 Tiger&蘋果爸 于 2016-06-03, 03:59

li60830 寫到:為什麼我下載不了啊~樓主大人~
已經重新上傳LISP附件囉~
竊喜

但是程式執行是失敗的~
局部放大中心點:
執行完就結束了...
愛哭

____________________________________________________________________________________
avatar
Tiger&蘋果爸
系統管理員
系統管理員

文章總數 : 17189
年齡 : 41
來自 : 台北市文山區
職業 : AutoCAD顧問
愛好 : 蹓狗/戶外活動/拍照
個性 : 幽默/樂觀/善良
使用年資 : 15↑
使用版本 : AutoCAD 2016
經驗值 : 64592
威望值 : 12753
注冊日期 : 2008-04-23
2D基礎函授 2D進階函授 3D基礎函授 https://i11.servimg.com/u/f11/19/71/67/71/2d3d10.png2D+3D線上 顧問外掛程式 經典問與答讀者 藍鵲1號
2009聚會勳章 2010聚會勳章 2011聚會勳章 2012聚會勳章 2013勳章-2D基礎 2014聚會勳章 2015聚會勳章 2016聚會勳章 串連貼紙成功 男 水瓶座 兔

http://mypaper.pchome.com.tw/kv1012tiger

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 stephen-peng 于 2016-06-03, 06:26

Tiger&蘋果爸 寫到:
li60830 寫到:為什麼我下載不了啊~樓主大人~
已經重新上傳LISP附件囉~
竊喜

但是程式執行是失敗的~
局部放大中心點:
執行完就結束了...
愛哭

感謝無私的分享
相當完整的工具有些小瑕疵,建議稍做修正 竊喜

代碼:

(setvar "CELTYPE" "PHANTOM");不是每張圖都有的線形
 (command "linetype" "l" "PHANTOM" "" "" "s" "PHANTOM" "");改為載入線形避免錯誤
附件
djh_220.zip 您無權下載這里的附件。(2 Kb) 下載 9 次
avatar
stephen-peng
一般會員
一般會員

文章總數 : 9
年齡 : 46
來自 : 板橋區
職業 : 工程師
愛好 : 電腦維修
個性 : 內向
使用年資 : 20年
使用版本 : 2014
經驗值 : 658
威望值 : 24
注冊日期 : 2016-03-15
男 處女座 豬

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 Tiger&蘋果爸 于 2016-06-03, 07:17

stephen-peng 寫到:
感謝無私的分享
相當完整的工具有些小瑕疵,建議稍做修正 竊喜
代碼:

(setvar "CELTYPE" "PHANTOM");不是每張圖都有的線形
 (command "linetype" "l" "PHANTOM" "" "" "s" "PHANTOM" "");改為載入線形避免錯誤
原來是線型啊!
還沒有空看程式說,謝謝 stephen-peng大 熱心除錯!
讚啦!!

____________________________________________________________________________________
avatar
Tiger&蘋果爸
系統管理員
系統管理員

文章總數 : 17189
年齡 : 41
來自 : 台北市文山區
職業 : AutoCAD顧問
愛好 : 蹓狗/戶外活動/拍照
個性 : 幽默/樂觀/善良
使用年資 : 15↑
使用版本 : AutoCAD 2016
經驗值 : 64592
威望值 : 12753
注冊日期 : 2008-04-23
2D基礎函授 2D進階函授 3D基礎函授 https://i11.servimg.com/u/f11/19/71/67/71/2d3d10.png2D+3D線上 顧問外掛程式 經典問與答讀者 藍鵲1號
2009聚會勳章 2010聚會勳章 2011聚會勳章 2012聚會勳章 2013勳章-2D基礎 2014聚會勳章 2015聚會勳章 2016聚會勳章 串連貼紙成功 男 水瓶座 兔

http://mypaper.pchome.com.tw/kv1012tiger

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 Atsai 于 2016-06-03, 09:05

代碼:

;;--------------------------------------------------------------
(defun exp_insert(/ en-name)
  (setq en (entnext sn1))
  (while (/= en nil)
     ;(setq en-name (dxfa 0 en))
          (setq en-name (cdr (assoc 0 (entget en))));因為少了dxfa函數,所以改成下面這一列就好了。
     (if (= en-name "INSERT")(command "explode" en))
     (setq en (entnext en))
  )
)

除了上面的線型問題,還要再改一下這一列,就可以了。
avatar
Atsai
中級會員
中級會員

文章總數 : 115
年齡 : 42
來自 : 台中
職業 : 工程
愛好 : 看漫畫
個性 : 樂天
使用年資 : 10
使用版本 : 2010
AutoCAD基礎篇等級 : 10星級
積分 : 7
經驗值 : 2900
威望值 : 337
注冊日期 : 2012-04-06
男 金牛座 兔

回頂端 向下

回復: [討論]局部放大功能無法修剪圖塊!

發表 由 Tiger&蘋果爸 于 2016-06-03, 09:16

Atsai 寫到:
代碼:

;;--------------------------------------------------------------
(defun exp_insert(/ en-name)
  (setq en (entnext sn1))
  (while (/= en nil)
  ;(setq en-name (dxfa 0 en))
          (setq en-name (cdr (assoc 0 (entget en))));因為少了dxfa函數,所以改成下面這一列就好了。
  (if (= en-name "INSERT")(command "explode" en))
  (setq en (entnext en))
  )
)

除了上面的線型問題,還要再改一下這一列,就可以了。
多謝Atsai熱心指導。
真是感恩喔~
害羞

____________________________________________________________________________________
avatar
Tiger&蘋果爸
系統管理員
系統管理員

文章總數 : 17189
年齡 : 41
來自 : 台北市文山區
職業 : AutoCAD顧問
愛好 : 蹓狗/戶外活動/拍照
個性 : 幽默/樂觀/善良
使用年資 : 15↑
使用版本 : AutoCAD 2016
經驗值 : 64592
威望值 : 12753
注冊日期 : 2008-04-23
2D基礎函授 2D進階函授 3D基礎函授 https://i11.servimg.com/u/f11/19/71/67/71/2d3d10.png2D+3D線上 顧問外掛程式 經典問與答讀者 藍鵲1號
2009聚會勳章 2010聚會勳章 2011聚會勳章 2012聚會勳章 2013勳章-2D基礎 2014聚會勳章 2015聚會勳章 2016聚會勳章 串連貼紙成功 男 水瓶座 兔

http://mypaper.pchome.com.tw/kv1012tiger

回頂端 向下

上一篇主題 下一篇主題 回頂端


 
這個論壇的權限:
無法 在這個版面回復文章