[討論]請教線轉為複線，或是聚合線轉為複線的作法?

Andy122333 寫到:各位好，請教是否有線轉為複線，或是聚合線轉為複線的作法?
否則...一線段一線段的畫...快瘋了我....    
先謝謝大家囉~~~

代碼:


(defun c:pl2ml ( / e i l s )
    (if (setq s (ssget '((0 . "LWPOLYLINE"))))
        (repeat (setq i (sslength s))
            (setq e (ssname s (setq i (1- i)))
                  l (entget e)
            )
            (apply 'command
                (append '("_.mline")
                    (apply 'append
                        (mapcar
                            (function
                                (lambda ( x )
                                    (list "_non" (trans (cdr x) e 1))
                                )
                            )
                            (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) l)
                        )
                    )
                    (if (= 1 (logand 1 (cdr (assoc 70 l)))) '("_C") '(""))
                )
            )
        )
    )
    (princ)
)


Tiger&蘋果爸 寫到: 謝謝熱心程式分享~< 積分 +1>
[公告]關於團隊成員的回文及貢獻

代碼:

(defun c:l2ml()
(setq mysset (ssget))
(setq mylength (sslength mysset))
(setq counter 0)
(while (< counter mylength)
   (setq obj (ssname mysset counter))
   (setq data (entget obj))
   (setq pt1 (cdr (assoc 10 data)))
   (setq pt2 (cdr (assoc 11 data)))
   (command "mline" "style" "standard" pt1 pt2 "")
   (entdel obj)
   (setq counter (+ 1 counter))
)
(princ)
)


Tiger&蘋果爸 寫到:沒辦法，這個只能借助程式！
所以得一條一條畫～
不知道你是什麼樣的需求要這樣做！